Java5 configureClassNode does not take care of parameter annotations

void testParameterAnnotation() { 

        GroovyClassLoader gcl = new GroovyClassLoader() 

        gcl.parseClass """ 
            import java.lang.annotation.* 

            @Target(ElementType.METHOD) 
            @Retention(RetentionPolicy.RUNTIME) 
            @interface MethodAnnotation {} 

            @Target(ElementType.PARAMETER) 
            @Retention(RetentionPolicy.RUNTIME) 
            @interface ParameterAnnotation {} 

            interface MyInterface { 
                @MethodAnnotation 
                def method(@ParameterAnnotation def param) 
            } 
        """ 

        GroovyCodeSource codeSource = new GroovyCodeSource(""" 
            class MyInterfaceImpl implements MyInterface { 
                def method(def param) {} 
            } 
        """, "script" + System.currentTimeMillis() + ".groovy", "/groovy/script") 

        CompilationUnit cu = new CompilationUnit(CompilerConfiguration.DEFAULT, codeSource.codeSource, gcl) 
        cu.addSource(codeSource.getName(), codeSource.scriptText); 
        cu.compile(CompilePhase.FINALIZATION.phaseNumber) 

        def classNode = cu.getClassNode("MyInterfaceImpl") 
        def interfaceClassNode = classNode.getInterfaces().find { it.nameWithoutPackage == 'MyInterface' } 

        def methodNode = interfaceClassNode.getDeclaredMethods("method")[0] 

        // check if the AnnotationNode for 'MethodAnnotation' has been created 
        assert methodNode.getAnnotations().any { AnnotationNode an -> an.classNode.nameWithoutPackage == 'MethodAnnotation' } 
        
        // this one will fail, since parameter annotations are ignored by Java5Plugin (and above) 
        assert methodNode.getParameters()[0].getAnnotations().any { AnnotationNode an -> an.classNode.nameWithoutPackage == 'ParameterAnnotation' } 
}