findResult object/collection/map enhancement patch

After some discussion on twitter, the map version of this might be a little screwy. I was trying to mimic the existing map.find and map.findAll in what they returned, but the user would have access to both the key and value in the closure so if they really wanted a Map.Entry they could create it for themselves. This current version probably violates the principle of least surprise.

If others agree, I could refactor the patch tomorrow to switch the map version to match the object/collection version.

There's also been some discussion about the name findResult and findAllResults. I'm open to other suggestions, it was the best thing that I could think of that implied both finding and transforming. I'm not aware of a similar construct in other languages (I checked ruby/python/clojure/scala and didn't see anything) that might give a common name that is used for this kind of method.

I am wondering about the usage a bit.. say we have a list of n entries and we define f(liston.find

), having the same result as your findResult, then the major difference for this is, that the function f is applied one more time here, than in with findResult. Looking at O(n) vs. O(n+1) function calls, I see no reason to have this. It makes more sense if the result will be in the first elements, then you have a low n, and the n+1 makes a difference. But still the biggest ddifference would be O(1) vs O(2). Usually, if f is very expensive, then I split f into two parts, one that tells me if f should be applied and one that does the actual transformation.

So what I would like to see are some (nonabstract) use cases as of how this method will be a real help to someone. You said there had been some twitter discussions... then it should be easy to give a few examples that helps us to see the true value of this method.

Jochen, you're correct that calling

f( list.find { f(it) != null } )

is equivalent in many cases and that this

list.findResult { f(it) }

is mostly just a more readable version. The situations where it really matters is when f() is either expensive (or of unknown expense), or if calling f() has side effects that are not safe to repeat in a second call (not idempotent).

One type of problem that findResult is useful for is when implementing a chain of responsibility type pattern, where the collection we're iterating over is a list of closures/objects where each of them is given a chance to handle a request till one of them finds an answer.

This is the problem that spurred this patch in the first place on twitter. Rob Fletcher was implementing an url rewriting using a set of rules, each of which could potentially handle the url and return the rewritten url (http://bit.ly/anf4EL). The return value from each rule is the rewritten rule. Here was his solution:

String rewrite (String url) {
    for (rule in rules) {
        def rewrittenUrl = rule.handle(url)
        if (rewrittenUrl) return rewrittenUrl
    }
    return url
}

With this patch, he would have been able to use:

String rewrite (String url) {
    rules.findResult { rule.handle(url) } ?: url
}

Which I think is much more readable and maintainable.

Here's another example from the grails code base that is currently required to use a "for" loop with a local variable

// from: BuildSettings.groovy

private getFirstPropertyValue(List<String> propertyNames, Properties props, String defaultValue) {
    def value
    for(String p in propertyNames ) {
        value = getValueFromSystemOrBuild(p, props)
        if(value!=null) break
    }
    return value ?: defaultValue
}

With findResult, it could be turned into:

private getFirstPropertyValue(List<String> propertyNames, Properties props, String defaultValue) {
    propertyNames.findResult { getValueFromSystemOrBuild(it, props)  } ?: defaultValue
}

From the groovy codebase, using the map version of findAllResults this:

// ConfigObject.groovy
private convertValuesToString(props) {
    def newProps = [:]
    for(e in props) {
        newProps[e.key] = e.value?.toString()
    }
    return newProps
}

becomes:

private convertValuesToString(props) {
    props.findAllResults { it.value?.toString() }
}

A few other examples that come to mind that could use findResult or findAllResults are:

• a List of paths/file handles, grep each file in the list with a regular expression with wildcards, return the file and matched text in the first one hit
• You have a grails service that can take an url, download the web page and extract contact information. With a list of URLs, you could use urls.findAllResults { webService.extractContactInfo(url) }

  to get all the contact info aff all the web pages

• implementing grails-like UrlMappings, similar to the rewrite rules above where the first url mapping that matches returns the controller/action to forward to urlMappings.findResult { it.handle(url) }

Good points, I think you're probably right that inject is good enough and there isn't as much of a need for findAllResults.

Inject can do everything that findAllResults can, without running f() extra times. I do think findAllResults is a little clearer in what's going on:

def list = [1, 2, 3, 4]
assert(["1", "2"] == list.inject([]) { newList, val -> if (val < 3) newList << "$val"; newList })
// versus
assert(["1", "2"] == list.findAllResults { if (it < 3) "$it" })

But inject has more flexibility as it can return things other than lists (and it's already in the code base . It could be added in later if we find there is demand for it if findResult gets added and people think that findAllResults is a natural and expected extension.

findResult is really the more important and, I think, valuable part of the patch. I think your suggestion to add an optional default parameter is a good one as I do think that many of the use cases for findResult would want a default value.

I'll modify the patch tonight to remove findAllResults, add a optional default to find result, and change the map version of findResult to just return the non-null result of the closure (as per my first comment above) rather than a Map.Entry.

updated patch that removes findAllResults, changes map version to return just the result instead of a Map.Entry and adds the ability to pass a default parameter

I've finished the modifications mentioned above. The latest patch ("findResult_with_defaultResult.patch") has these changes from the original:

• removed findAllResults as inject can fulfill the role for the most part, this could be added later if desired.
• modified the map version of findResult so that it returns the closure result rather than a Map.Entry with the value as the closure result, this is more intuitive and someone could always construct a Map.Entry to return if that's what they want, example:

assert "I found c:3" == [a: 1, c:3].findResult { 
    if (it.value > 2) return "I found ${it.key}:${it.value}"
}

• added an optional defaultResult parameter

assert "default" == [1, 2, 3].findResult("default") { 
    if (it == 8) return "never get here"
}

All tests have been updated to exercise the new code and are passing. I'd be interested to hear any feedback and if there are other changes that people feel would make this even more valuable.

It would be nice to consider whether there is a more general solution to this. One that also fixed GROOVY-3526 would be good.

BTW: Great to have a patch with tests and doco!

Thanks for this implementation!

actually can we change the name of the issue (remove findAllResults), because only findResult has been added, it´s misleading and appears in the release notes that way
my 2ct: inject is more powerful and can do everything that findAllResults can do and more, but findAllResults is so much more intuitive - imho it should be added, doesnt do harm and you would always think: now there is find, findAll, findResult ... so where is findAllResults?

I know this issue is closed but I tend to agree that findAllResults would be useful. It does look like inject() could achieve the same but I wouldn't have thought to use it. This is one case where the implementation doesn't match the mental model.

Interestingly, I also found this question on StackOverlow:

http://stackoverflow.com/questions/5789795/collection-findallresults-in-groovy-1-7-5

I have another example where inject is even more verbose:

def text = "file1: could not\nline2\nfile2: could not\nline3\n"
println text.readLines().inject([]) { l, v -> l << v.find(~/(\S+): could not/)

}

In case there is further interest, I created GROOVY-4899