groovy.sql.Sql throws ClassNotFoundException when called via GroovyShell that explicitly adds jdbc jar to classpath

You can resolve the issue by setting the thread context loader

hmm...if that is not enough, then I suggest you call DriverManage.registerDriver(new com.mysql.jdbc.Driver())

That doesn't help.

Changing the "inner" script to

import groovy.sql.Sql
import java.sql.DriverManager
DriverManager.registerDriver(new com.mysql.jdbc.Driver())
DriverManager.drivers.each

assert null != Sql.newInstance("jdbc:mysql://localhost:3306/db", "user", "pass", "com.mysql.jdbc.Driver")

The error remains the same: SQLException: No suitable driver found

On the mac, there are no drivers printed. On solaris, I get only sun.jdbc.odbc.JdbcOdbcDriver. It appears that registerDriver call silently fails.

In all cases, of course, passing the mysql jar to groovy with the -cp parameter works. The following works (obviously):

def cp = []
cp << "mysql-connector-java-5.1.6-bin.jar"

script = """
import groovy.sql.Sql
assert null != new com.mysql.jdbc.Driver()
assert null != Sql.newInstance("jdbc:mysql://localhost:3306/db", "user", "pass", "com.mysql.jdbc.Driver")
"""

def cmd = ["groovy", "-cp", cp.join(":"), "-e", script]
println cmd.execute().text

I'm trying to use GroovyShell from within gradle to execute a script that executes some SQL and I'm having the same problem.

Maybe this helps to further track it down:

DriverManager.setLogStream(System.out) will enable the log output of the driver manager. I also get the unsuitable driver message, but obviously all could be fine with the driver registration as such, but for some reason the driver manager thinks that one is not "allowed" to load it.

It logs: skipping: driver[className=org.postgresql.Driver,org.postgresql.Driver@466a3728]

The DriverManager's javadoc says: "If the caller does not have permission to load the driver then skip it."

So it still appears to be some classloading issue...

Basically I tried this in a gradle task:

compilerConfiguration = new CompilerConfiguration()
compilerConfiguration.classpath = runtimeClasspath.asPath
groovyShell = new GroovyShell(compilerConfiguration)
groovyShell.run(file('someScriptUsingGroovySql.groovy'), 'someArgs')

This script does Sql.newInstance for a valid PostgreSQL url. The classpath contains the postgres jdbc driver (I can do Class.forName("org.postgresql.Driver") without an exception). I tried Sql.loadDriver, but all boils down to the driver manager ignoring/"skipping" the jdbc driver class despite it is obviously detected.

Note: when passing the classpath to groovy -cp everything works fine.

Solved for me after digging through many forum posts: GroovyShell needs to use a root loader to find the JDBC driver which includes the jar as part of its loader configuration. Just using the compiler configuration is not enough... In my case, for gradle it looks like:

        loaderConfiguration = new LoaderConfiguration()
        loaderConfiguration.addClassPath(runtimeClasspath.asPath)
        rootLoader = new RootLoader(loaderConfiguration)

        compilerConfiguration = new CompilerConfiguration()
        compilerConfiguration.classpath = runtimeClasspath.asPath

        groovyShell = new GroovyShell(rootLoader, new Binding(), compilerConfiguration)
        groovyShell.run(file('someScriptUsingGroovySql.groovy'), 'someArgs')

runtimeClasspath.asPath contains all jars including the JDBC driver. So now it works... Finally... I suppose that this will also work when done just with Groovy alone. Compare: http://groovy.codehaus.org/How+can+I+dynamically+add+a+library+to+the+classpath

Probably a better HOWTO or FAQ entry for "Sql" in combination with GroovyShell would be helpful for others...

I had the same issue running a script from the command line (i.e. $ groovy myscript.groovy ). The solution I found here is to add the @GrabConfig(systemClassLoader=true) annotation at the top of the file.

@GrabConfig(systemClassLoader = true)
@Grab(group='mysql', module='mysql-connector-java', version='5.1.21')
import groovy.sql.Sql

def sql = Sql.newInstance("jdbc:mysql://localhost:3306/db", "user", "pass", "com.mysql.jdbc.Driver")

println(sql)